You read a scientific article, for example:
Pernis, A.B. (2002) The Role of IRF-4 in B and T Cell Activation and Differentiation, Journal of Interferon and Cytokine Research 22:111–120
The signaling pathway data in this paper can be coded in DSM Language as follows:
default[nucl];
NF-kB -> IRF4;
STAT6-P -> IRF4;
\IRF4, PU-1\ -> *Ig-K, Ig-L, CD20*;
\IRF4, Spi-B\ -> *Ig-k, Ig-l*;
\IRF4, E47\ -> *Ig-k, Ig-l*;
CIITA -> MHC_II;
@1 := {\NF-kB, STAT6-P, IRF4\ -> CD23};
PRDI-BF1 -| *IFN-b, CIITA, c-Myc, IRF4*;
PRDI-BF1 -| @1;
BCL6 -| *CD23, STAT6-P, IRF4*;
default[cytomb];
@2 := {STAT6 => STAT6-P};
(Ag, TCR) -> NF-kB;
(Ag, BCR) -> NF-kB;
(CD40, CD40L) -> NF-kB;
(CD40, CD40L) -| BCL6;
(IL4, IL4-R) -> @2;
(CD40, CD40L) -> BCL6;
# translocations
STAT6-P[cytomb] ~> STAT6-P[nucl];
NF-kB[cytomb] ~> NF-kB[nucl];
BCL6[cytomb] ~> BCL6[nucl];
|
In the Dynamic Signaling Maps console editor you can open an empty DSM Language file and enter the text above:
After you Save the file you can click the Translate button to verify the consistency of the data you have just entered:
Oops! An inconsistency -- statements in lines 18 and 20 contradict each other. They represent the inhibition and activation, respectively, of the BCL6 molecule by the same complex, CD40 + CD40L.
We intentionally inserted line 20, which doesn't correspond to any data in the article, to simulate a real-life situation where data from different sources are contradictory and to show you how the DSM Translator intercepts such situations. What you need to do at this point, assuming you have determined that line 20 contains wrong data, is simply delete all the text in the "textarea" element below Edit line 20 in the dialog above and then hit the Update, Save, & Translate again button:
Success! Now you can click the Map button and choose the output format:
Here is a screen shot of your signaling map:
If you wish to "zoom in" on details of this map here it is in PDF format. If you want to include and edit it in a PowerPoint presentation then you can map out the signaling pathway data in EMF format.
With an Internet-enabled computer handy you can enter the data in the DSM console while you read the article at your desk, at the library, or during your flight. In this particular example, entering the signaling pathway data in DSM Language while you read the article will extend your reading time by about ten minutes. And the graphical map is just "one click away"!
If you actually try finding that journal then you will discover a second article, on a very similar topic, in the same issue:
Marecki, S. and Fenton, M.J. (2002) The Role of IRF-4 in Transcriptional Regulation, Journal of Interferon and Cytokine Research 22:121–133
Want an updated signaling map, which also takes into account the data in the second paper? Just edit your file in the DSM console editor to include the new data and then hit Translate and Map again — it's as simple as that!
Here is the signaling data corresponding to the second article:
default[nucl];
PU-1-P -> *c-fms, Ig-k, Ig-l, Ig-m, CD11b, IL-1b, gp91PHOX*;
PU-1-P -> *Mf_scavenger_R, CD20, Mf_mannose_R*;
PU-1-P -| *I-Ab/MHC_II, MMP-1, CD11c*;
(IRF1, IRF1) -> MHC_I;
(IRF1, ICSBP) -| MHC_I;
*IRF4, ICSBP, IRF2* -| ISG15;
*ICSBP, IRF4* -| *_2-5-OAS, H-2Ld*;
ICSBP -> ICSBP;
ICSBP -> IL12;
@3 := {ISGF3g -> IFN-g_responsive_genes};
(ICSBP, ISGF3g) -| @3;
(IRF4, STAT6) -> CD23;
(IRF4, BCL6) -| CD23;
(IRF1, IRF2, IRF4, PU-1-P) -> IL1-b;
(ICSBP, PU-1-P) -> IL1-b;
@6 := {ICSBP -> IL18};
ICSBP -> CD11b;
@4 := {PU-1 => PU-1-P};
CK2 -> @4;
default[cytomb];
(IFN-g, IFN-g-R) -> II_msg;
II_msg[cytomb] ~> II_msg[cyto];
II_msg[cyto] -> MAPK[cyto];
CK2[cyto] ~> CK2[nucl];
@5 := {IRF4[cyto] ~> IRF4[nucl]};
LPS[extr] ~> LPS[cyto];
default[cyto];
\STAT, p48/IRF9\ => ISGF3g;
LPS -> MAPK;
MAPK -> CK2;
LPS -> @5;
MAPK -> STAT;
LPS[cyto] ~> LPS[nucl];
LPS[nucl] -> @6;
ISGF3g[cyto] ~> ISGF3g[nucl];
PU-1 == SPI-1;
ICSBP == IRF8;
|
Upon entering this data in a separate file and running Translate and Map you get the signaling map below (display it in PDF format):
To have the signaling data from both papers in one diagram you can simply append the new data to the previous file. Here is the combined data:
#JOURNAL OF INTERFERON AND CYTOKINE RESEARCH 22:111–120 (2002)
# The Role of IRF-4 in B and T Cell Activation and Differentiation
# ALESSANDRA B. PERNIS
default[nucl];
NF-kB -> IRF4;
STAT6-P -> IRF4;
\IRF4, PU-1-P\ -> *Ig-K, Ig-L, CD20*;
\IRF4, Spi-B\ -> *Ig-k, Ig-l*;
\IRF4, E47\ -> *Ig-k, Ig-l*;
CIITA -> MHC_II;
@1 := {\NF-kB, STAT6-P, IRF4\ -> CD23};
PRDI-BF1 -| *IFN-b, CIITA, c-Myc, IRF4*;
PRDI-BF1 -| @1;
BCL6 -| *CD23, STAT6-P, IRF4*;
default[cytomb];
@2 := {STAT6 => STAT6-P};
(Ag, TCR) -> NF-kB;
(Ag, BCR) -> NF-kB;
(CD40, CD40L) -> NF-kB;
(CD40, CD40L) -| BCL6;
(IL4, IL4-R) -> @2;
# translocations
STAT6-P[cytomb] ~> STAT6-P[nucl];
NF-kB[cytomb] ~> NF-kB[nucl];
BCL6[cytomb] ~> BCL6[nucl];
PRDI-BF1 == Blimp1;
# JOURNAL OF INTERFERON AND CYTOKINE RESEARCH 22:121–133 (2002)
# The Role of IRF-4 in Transcriptional Regulation
# SYLVIA MARECKI and MATTHEW J. FENTON
default[nucl];
PU-1-P -> *c-fms, Ig-k, Ig-l, Ig-m, CD11b, IL-1b, gp91PHOX*;
PU-1-P -> *Mf_scavenger_R, CD20, Mf_mannose_R*;
PU-1-P -| *I-Ab/MHC_II, MMP-1, CD11c*;
(IRF1, IRF1) -> MHC_I;
(IRF1, ICSBP) -| MHC_I;
*IRF4, ICSBP, IRF2* -| ISG15;
*ICSBP, IRF4* -| *_2-5-OAS, H-2Ld*;
ICSBP -> ICSBP;
ICSBP -> IL12;
@3 := {ISGF3g -> IFN-g_responsive_genes};
(ICSBP, ISGF3g) -| @3;
(IRF4, STAT6) -> CD23;
(IRF4, BCL6) -| CD23;
(IRF1, IRF2, IRF4, PU-1-P) -> IL1-b;
(ICSBP, PU-1-P) -> IL1-b;
@6 := {ICSBP -> IL18};
ICSBP -> CD11b;
@4 := {PU-1 => PU-1-P};
CK2 -> @4;
default[cytomb];
(IFN-g, IFN-g-R) -> II_msg;
II_msg[cytomb] ~> II_msg[cyto];
II_msg[cyto] -> MAPK[cyto];
CK2[cyto] ~> CK2[nucl];
@5 := {IRF4[cyto] ~> IRF4[nucl]};
LPS[extr] ~> LPS[cyto];
default[cyto];
\STAT, p48/IRF9\ => ISGF3g;
LPS -> MAPK;
MAPK -> CK2;
LPS -> @5;
MAPK -> STAT;
LPS[cyto] ~> LPS[nucl];
LPS[nucl] -> @6;
ISGF3g[cyto] ~> ISGF3g[nucl];
PU-1 == SPI-1;
ICSBP == IRF8;
|
Notes. (1) While in the first article explicit reference is made to STAT6 and its phosphorylated form, in the second article STAT proteins are only generically referred to; we have to leave it like that until we can get more information on the particular STAT proteins involved. (2) In the second paper, we get an interesting piece of new information: PU.1 (or PU-1, above) needs to be phosphorylated to be active. Since we entered this factor as PU-1 in the data from the first paper and as PU-1-P in the data from the second paper, to avoid displaying it as two different molecules (PU-1 and PU-1-P) we have edited line 8, which is based on data from the first paper
\IRF4, PU-1\ -> *Ig-K, Ig-L, CD20*; |
as follows:
\IRF4, PU-1-P\ -> *Ig-K, Ig-L, CD20*; |
We can now run Translate and Map the combined data:
Check out the final map in PDF format and this file in PPT format produced after some customization in PowerPoint.